monday items, people and boards

What each column type gives the formula; the item itself; connected items, subitems and mirrors; people and teams; every item of the group or the board; keeping every item up to date.

What each column gives the formula

The item’s name, group and board are {item's Name} and the board and group references (see Referring to columns). In the recipes created before November 2026 several values are joined by + instead of , .

Connected items and subitems new recipes

A Connect boards, Dependency or Subitems column gives only the IDs of the linked items. These functions read the rest from monday, one value per linked item:

=LIST.JOIN(MONDAY.ITEM.NAME({item's Projects}))
=SUM(VALUE(MONDAY.ITEM.COLUMN({item's Orders}, "Amount")))                       → the total of the connected orders
=LIST.JOIN(TABLE.COLUMN(TABLE.WHERE(MONDAY.ITEMS({item's Projects}, "Status"), "Status", "Working on it"), "Name"))
                                                                                  → the connected projects in progress
=LIST.JOIN(MONDAY.ITEM.NAME({item's Subitems}), CHAR(10))                         → the subitems, one per line

Values of other boards arrive as text: numbers need VALUE, as above.

The item itself new recipes

Without an argument, MONDAY.ITEM.CREATED(), MONDAY.ITEM.UPDATED(), MONDAY.ITEM.CREATOR(), MONDAY.ITEM.LAST_UPDATE(), MONDAY.ITEM.URL() and MONDAY.ITEM.ID() give the details of the item the automation runs on:

="Created by " & MONDAY.ITEM.CREATOR() & " on " & DATE.FORMAT(MONDAY.ITEM.CREATED(), "D MMMM YYYY")

People and teams

The argument is a People column. Each function gives one value per person; teams are skipped.

A detail the person hasn’t filled in on monday is empty. To write people into a People column, give their emails: MONDAY.PEOPLE.EMAIL({item's Owner}).

Every item of the group or the board new recipes

Numbers come as numbers, so totals work directly:

=ROUND({item's Cost} / SUM(MONDAY.GROUP.COLUMN("Cost")), 4)          → the item's share of the group
=XMATCH({item's Score}, SORT(MONDAY.BOARD.COLUMN("Score"), 1, -1))     → the item's rank on the board
=COUNTA(MONDAY.GROUP.COLUMN("Name"))                                   → how many items in the group

Up to 1,000 items are read.

Keeping every item up to date

When one item’s Cost changes, every share in the group changes. The recalculate block calculates a formula for every item of the group, or of the board, and writes the result only where it changed:

• When Cost changes → recalculate the share for every item of the group. Choose Cost as the trigger, not the column the block writes, or the automation would run again on its own result.
• Every day at 8:00 → recalculate ROUND(MONDAY.CURRENCY({item's Price}, "EUR", "USD"), 2) for every item of the board, so converted prices follow the day’s rate (see Converting currencies).

The block gives the next step of the workflow how many items it calculated, wrote and found with errors. A recalculation that can’t finish within a minute stops and says so: recalculate the group instead of the board, or ask us to run it in the background.

Credits