Ideas

Formulas ready to copy

Solutions to everyday monday.com problems. Copy a formula, paste it into General Caster and replace the column references with your own.

Column references

References like {item's Date} are examples. In the formula editor, delete them and click the button of your own column at the bottom of the editor to insert the right reference. How references work

Emails of the assignees New

People Text

Write the email addresses of the people assigned to an item, for example to use them in an email integration or an export.

Example General Caster

Item	Person	Emails
Kickoff	MMarco	[email protected]
Review	GGiulia	[email protected]

MONDAY.PEOPLE.EMAIL({item's Person})

You need: One People column and one Text column
Recipe: When column changes, perform formula and cast result to column
Functions: MONDAY.PEOPLE.EMAIL

Assign by department New

Status People

When the department of a request changes, assign it to the right person using their email.

Example General Caster

Request	Department	Owner
Ticket 311	Support	MMarco
Ticket 312	Sales	AAnna

SWITCH({item's Department}, "Sales", "[email protected]", "Support", "[email protected]", "DO-NOTHING")

You need: One Status column and one People column (Standard plan or higher)
Recipe: When column changes, perform formula and cast result to column
Functions: SWITCH

Quarter from a date New

Date Status

Label each item with its quarter, like Q4 2026, to group and filter the board by quarter. Missing labels are created automatically.

Example General Caster

Invoice	Date	Quarter
Invoice 104	2026-10-29	Q4 2026
Invoice 105	2027-02-03	Q1 2027

CONCATENATE("Q", ROUNDUP(MONTH(DATEVALUE({item's Date})) / 3, 0), " ", YEAR(DATEVALUE({item's Date})))

You need: One Date column and one Status (or Dropdown, or Text) column
Recipe: When column changes, perform formula and cast result to column
Functions: CONCATENATE ROUNDUP MONTH DATEVALUE YEAR

Week from a date New

Date Week

Fill a Week column with the week (Monday to Sunday) that contains the date.

Example General Caster

Item	Date	Week
Sprint review	2026-10-29	Oct 26 – Nov 1
Retro	2026-11-08	Nov 2 – Nov 8

CONCATENATE(TEXT(DATEVALUE({item's Date}) - WEEKDAY(DATEVALUE({item's Date}), 3), "YYYY-MM-DD"), "+", TEXT(DATEVALUE({item's Date}) - WEEKDAY(DATEVALUE({item's Date}), 3) + 6, "YYYY-MM-DD"))

You need: One Date column and one Week column
Recipe: When column changes, perform formula and cast result to column
Functions: CONCATENATE TEXT DATEVALUE WEEKDAY

On time or late New

Two dates Status

When an order is delivered, compare the delivery date with the due date and set On time or Late.

Example General Caster

Order	Due date	Delivered	Delivery
Order 88	2026-10-22	2026-10-25	Late
Order 89	2026-10-22	2026-10-20	On time

IF(DATEVALUE({item's Delivered}) <= DATEVALUE({item's Due date}), "On time", "Late")

You need: Two Date columns and one Status column
Recipe: When column changes, perform formula and cast result to column
Functions: IF DATEVALUE

Days in a timeline New

Timeline Numbers

Count the calendar days of a timeline, weekends included, first and last day included.

Example General Caster

Item	Timeline	Days
Sprint 1	Mar 2 – Mar 20	19
Sprint 2	Apr 6 – Apr 10	5

DAYS(DATEVALUE(RIGHT({item's Timeline}, 10)), DATEVALUE(LEFT({item's Timeline}, 10))) + 1

You need: One Timeline column and one Numbers column
Recipe: When column changes, perform formula and cast result to column
Functions: DAYS DATEVALUE RIGHT LEFT

Total with discount New

Numbers Numbers

Calculate the total of an order line from price, quantity and discount percentage, rounded to cents.

Example General Caster

Item	Price	Qty	Discount %	Total
Chairs	120	6	15	612
Cables	19.90	3	0	59.7

ROUND({item's Price} * {item's Quantity} * (1 - {item's Discount} / 100), 2)

You need: Three Numbers columns for the inputs and one for the total
Recipe: When any column changes, perform formula and cast result to column
Functions: ROUND

Profit margin New

Numbers Numbers

Calculate the margin percentage from price and cost, to sort products or deals by profitability.

Example General Caster

Product	Price	Cost	Margin %
Desk	250	180	28
Lamp	80	62	22.5

ROUND(({item's Price} - {item's Cost}) / {item's Price} * 100, 1)

You need: Two Numbers columns for price and cost and one for the margin
Recipe: When any column changes, perform formula and cast result to column
Functions: ROUND

Reorder when stock is low New

Numbers Checkbox

Check a Reorder checkbox when the stock falls below the reorder level, then let a monday.com automation notify the buyer.

Example General Caster

Product	Stock	Reorder level	Reorder
Paper	8	10
Toner	40	10

IF({item's Stock} < {item's Reorder level}, TRUE, FALSE)

You need: Two Numbers columns and one Checkbox column
Recipe: When any column changes, perform formula and cast result to column
Functions: IF

Project code New

Text + Date Text

Build a readable code from the first three letters of the client and the year and month of the project, like ACM-2610.

Example General Caster

Project	Client	Date	Code
Website	Acme Corp	2026-10-29	ACM-2610
App	Globex	2027-01-15	GLO-2701

CONCATENATE(UPPER(LEFT({item's Client}, 3)), "-", TEXT(DATEVALUE({item's Date}), "YYMM"))

You need: One Text column, one Date column and one Text column for the code
Recipe: When any column changes, perform formula and cast result to column
Functions: CONCATENATE UPPER LEFT TEXT DATEVALUE

Google Maps link from an address New

Text Link

Turn the address written in a Text column into a link that opens it in Google Maps.

Example General Caster

Store	Address	Map
North	Via Roma 1, Padua	Open map
South	Piazza Navona, Rome	Open map

CONCATENATE("https://www.google.com/maps/search/?api=1&query=", SUBSTITUTE({item's Address}, " ", "+"), ":Open map")

You need: One Text column and one Link column
Recipe: When column changes, perform formula and cast result to column
Functions: CONCATENATE SUBSTITUTE

Due date after N working days

Date + Numbers Date

When you set a start date, set the due date after the number of working days written in a Numbers column.

Example General Caster

Item	Date	Number	Due date
Design	2026-03-09	5	2026-03-16
Build	2026-03-16	10	2026-03-30

TEXT(WORKDAY(DATEVALUE({item's Date}), {item's Number}), "YYYY-MM-DD")

You need: Two Date columns and one Numbers column
Recipe: When any column changes, perform formula and cast result to column
Functions: TEXT WORKDAY DATEVALUE

Timeline from a date

Date Timeline

When you set a date, set a timeline that starts 7 days later and ends 21 days later.

Example General Caster

Item	Date	Timeline
Kickoff	2026-04-06	Apr 13 – Apr 27
Review	2026-05-04	May 11 – May 25

CONCATENATE(TEXT(DATEVALUE({item's Date}) + 7, "YYYY-MM-DD"), "+", TEXT(DATEVALUE({item's Date}) + 21, "YYYY-MM-DD"))

You need: One Date column and one Timeline column
Recipe: When column changes, perform formula and cast result to column
Functions: CONCATENATE TEXT DATEVALUE

Shift a timeline

Timeline Timeline

When you set a timeline, set another timeline moved 14 days into the future.

Example General Caster

Item	Timeline	Shifted
Phase 1	Jun 8 – Jun 19	Jun 22 – Jul 3
Phase 2	Jul 6 – Jul 10	Jul 20 – Jul 24

CONCATENATE(TEXT(DATEVALUE(LEFT({item's Timeline}, 10)) + 14, "YYYY-MM-DD"), "+", TEXT(DATEVALUE(RIGHT({item's Timeline}, 10)) + 14, "YYYY-MM-DD"))

You need: Two Timeline columns
Recipe: When column changes, perform formula and cast result to column
Functions: CONCATENATE TEXT DATEVALUE LEFT RIGHT

Next birthday

Date Date

When you set a birth date, set the date of the next birthday.

Example General Caster

Name	Birth Date	Next birthday
Anna	1985-11-20	2026-11-20
Marco	1990-03-14	2027-03-14

CONCATENATE(YEAR(TODAY()) + IF(TODAY() > DATEVALUE(CONCATENATE(YEAR(TODAY()), RIGHT({item's Birth Date}, 6))), 1, 0), RIGHT({item's Birth Date}, 6))

You need: Two Date columns
Recipe: When any column changes, perform formula and cast result to column
Functions: CONCATENATE YEAR TODAY IF DATEVALUE RIGHT

First Monday of the month

New item Date

When a task is created, set its due date to the first Monday of the current month.

Example General Caster

Item	Created	Due date
Monthly report	2026-10-02	2026-10-05
New task	2026-10-29	2026-10-05

TEXT(DATE(YEAR(TODAY()), MONTH(TODAY()), 7) - WEEKDAY(DATE(YEAR(TODAY()), MONTH(TODAY()), 7), 3), "YYYY-MM-DD")

You need: One Date column
Recipe: When an item is created, perform formula and cast result to column
Functions: TEXT DATE YEAR TODAY MONTH WEEKDAY

Working days in a timeline

Timeline Numbers

Count the working days between the start and the end of a timeline.

Example General Caster

Item	Timeline	Working days
Sprint 1	Mar 2 – Mar 20	15
Sprint 2	Apr 6 – Apr 10	5

NETWORKDAYS(DATEVALUE(LEFT({item's Timeline}, 10)), DATEVALUE(RIGHT({item's Timeline}, 10)))

You need: One Timeline column and one Numbers column
Recipe: When column changes, perform formula and cast result to column
Functions: NETWORKDAYS DATEVALUE LEFT RIGHT

Working hours between two dates

Date + time Numbers

Count the working hours between two dates with time, on a 09:00–18:00 schedule.

Example General Caster

Item	From	To	Hours
Ticket 1	Mon 09:00	Tue 13:00	13
Ticket 2	Wed 14:00	Thu 11:00	6

((NETWORKDAYS(DATEVALUE({item's From DateTime}), DATEVALUE({item's To DateTime})) - 1) * (TIMEVALUE("18:00") - TIMEVALUE("09:00")) + IF(NETWORKDAYS({item's To DateTime}, {item's To DateTime}), MEDIAN(MOD(TIMEVALUE({item's To DateTime}), 1), TIMEVALUE("18:00"), TIMEVALUE("09:00")), TIMEVALUE("18:00")) - MEDIAN(NETWORKDAYS(DATEVALUE({item's From DateTime}), DATEVALUE({item's From DateTime})) * MOD(TIMEVALUE({item's From DateTime}), 1), TIMEVALUE("18:00"), TIMEVALUE("09:00"))) * 24

You need: Two Date columns with time and one Numbers column
Recipe: When column changes, perform formula and cast result to column
Functions: NETWORKDAYS DATEVALUE TIMEVALUE IF MEDIAN MOD

Rating from a budget

Numbers Rating

Give each item a rating from 1 to 5 based on its budget.

Example General Caster

Project	Budget	Rating
Rebranding	82,000
New office	120,000

IF({item's Number} > 100000, 5, IF({item's Number} > 75000, 4, IF({item's Number} > 50000, 3, IF({item's Number} > 25000, 2, 1))))

You need: One Numbers column and one Rating column
Recipe: When column changes, perform formula and cast result to column
Functions: IF

Email address from a status

Status Email

Set a clickable email address based on the status of the item.

Example General Caster

Item	Status	Email
Order 1	Tim	Tim Apple
Order 2	Jeff	Jeff Amazon

SWITCH({item's Status}, "Tim", "[email protected]:Tim Apple", "Jeff", "[email protected]:Jeff Amazon", "")

You need: One Status column with the labels "Tim" and "Jeff", and one Email column
Recipe: When column changes, perform formula and cast result to column
Functions: SWITCH

Address from a location

Location Text

Copy the address of a Location column into a Text column.

Example General Caster

Store	Location	Address
North	Padua, Italy	Padua, Italy
South	Rome, Italy	Rome, Italy

RIGHT({item's Location}, LEN({item's Location}) - FIND(":", {item's Location}, FIND(":", {item's Location}) + 1))

You need: One Location column and one Text column
Recipe: When column changes, perform formula and cast result to column
Functions: RIGHT LEN FIND

WhatsApp link from a phone

Phone Link

Create a link that opens a WhatsApp chat with the phone number of the item.

Example General Caster

Contact	Phone	Link
Giulia	+39 333 123 4567	WhatsApp
John	+1 415 555 0101	WhatsApp

CONCATENATE("http://wa.me/", LEFT({item's Phone}, FIND(":", {item's Phone}) - 1), ":WhatsApp")

You need: One Phone column and one Link column
Recipe: When column changes, perform formula and cast result to column
Functions: CONCATENATE LEFT FIND

Count a word in subitems

Subitems Numbers

Count how many times "Apple" appears in a column of the subitems.

Example General Caster

Order	Subitems Text	Apples
Basket 1	Apple, Pear, Apple, Apple	3
Basket 2	Kiwi, Apple	1

(LEN({item's Subitems Text}) - LEN(SUBSTITUTE({item's Subitems Text}, "Apple", ""))) / LEN("Apple")

You need: One subitems summary column (you can hide it) and one Numbers column
Recipe: When any column changes, perform formula and cast result to column
Functions: LEN SUBSTITUTE

Last value of a mirrored column New

Mirror Text

Mirrored and subitems summary columns return all values joined by "+". Keep only the last one.

Example General Caster

Item	Mirrored Column	Last value
Doc A	Draft+Review+Approved	Approved
Doc B	Open+Closed	Closed

TRIM(RIGHT(SUBSTITUTE({item's Mirrored Column}, "+", REPT(" ", 999)), 999))

You need: One mirrored (or subitems summary) column and one Text column
Recipe: When any column changes, perform formula and cast result to column
Functions: TRIM RIGHT SUBSTITUTE REPT

Use cases

Workflows built with General Caster

Complete solutions that combine General Caster with monday.com automations.

Dependent board General Caster

When Timeline changes, perform formula and cast result to mirrored column

Task	Predecessor	Timeline
Install	Jun 1 – Jun 10	Jun 11 – Jun 16
Test	Jun 11 – Jun 16	Jun 17 – Jun 19

Cross-board dependencies

By Didier Bollag, Onboarding Success Manager at monday.com

The problem

Tasks in one board depend on tasks in another board, and any delay of the predecessors should move the dependent timelines. Dependency automations don't work across boards.

The solution

Mirror the predecessor timeline into the dependent board with "When column changes, perform formula and cast result to mirrored column" (the formula is just the timeline column). Then the item-level dependency automations of the dependent board move the timelines.

Dependency automations used in this workflow

Waterfall project General Caster

When Start changes, perform formula and cast result to End

TEXT(WORKDAY(DATEVALUE({item's Start}), {item's Work days}), "YYYY-MM-DD")

Task	Start	Work days	End	Timeline
Design	2026-03-09	5	2026-03-16	Mar 9 – Mar 16
Build	2026-03-16	10	2026-03-30	Mar 16 – Mar 30

Baseline of a waterfall project

By Didier Bollag, Onboarding Success Manager at monday.com

The problem

See how long a project will take from a start date and the work days each task needs.

The solution

One formula adds the work days to the start date, a second one builds the timeline from the two dates, and the dependency automation starts each task when its predecessor ends.

TEXT(WORKDAY(DATEVALUE({item.date}), {item.number}), "YYYY-MM-DD")

CONCATENATE({item.date_16}, "+", {item.date_17})

Built something clever with General Caster? We'd love to feature it.

Share your use case